root/HUD/hud_compensator.lsl

/////////////////
//
//  HUD_compensator.lsl 1 
//  by Max Case
//
//  This script allows you to set offsets/position info for HUDs
//  It will then compensate, depending on the position
//
//    I've left comments in the script on how to use this, so if you're not script-experienced, you can probably still use this, though,  
//  if you don't know scripting, this probably isn't of much interest to you, since you're probably not making HUDs.
//     
//  @todo if rezzed from inv, into world, or onto body even? asks to attach to a HUD point. Can even give user a choice via llDialog
//  @todo make flag for wether Requires HUD Attach point, or is any point allowed?
//  Use this in products you make, but don't just re-sell this script as-is - thanks.
//    -max
//////////////

//Global Vars
rotation GR_HUD_ROTATION = <0.000000, -0.000000, -0.000000, 1.000000>;
rotation GR_HUD_PREFS =  <-0.000000, -0.000000, 1.000000, 0.000000>;
//OFFSET - Offset is relative to BOTTOM RIGHT - towards inside of the screen - away from edge
vector GV_OFFSET =  <-0.087600, 0.329133, 0.142695>;
vector GV_HIDE_OFFSET = <-0.087600, -0.319792, 0.142695>;
vector GV_USER_OFFSET = <0,0,0>; //For show hide reset 

//BUTTONS
//Set to -1 to turn off. TO activate this functionality, set to the link number you want associted with the function
//BUTTONS

//To Flip HUD - say, for preferences on the back
integer GI_BUTTON_FLIP = -1; //PREFS
integer GI_BUTTON_FLIP_B = -1;

integer GI_BUTTON_HIDE = -1;
integer GI_BUTTON_SHOW = -1;

//Set to true if you want kill switch functionality on
// probably want this to be false on no copy objects :) 
integer GI_KILL_SWITCH = TRUE; 
//How many chances before i auto delete
integer GI_KILL_MAX = 7; 
//For the Kill Switch timer- gets multiplied - so, first wanrning is in TICKS second, then second is in TICKS*2, etc... up to the GI_KILL_MAX 
float TICKS = 60.0; 

//LINK CODE
//If you are using an external Show Button, this lets others know that SHOW / HIDE button triggered
integer SHOW_NUM =-239482;

//Start in flipped mode?
//Panel View default, TRUE  = prefs
integer GI_HUD_FLIPPED = FALSE; 
integer GI_VISIBLE = TRUE; //SHow hide flag

//Shouldnt have to mode below here.
integer GI_KILL_COUNTER = 0; //Just a global to track it.

list GL_HUD_NAMES = ["Center 2","Top Right","Top","Top Left","Center","Bottom Left","Bottom","Bottom Right"];
list GL_HUD_NUMBERS = ["31","32","33","34","35","36","37","38"];

integer LAST_ATTACH_POINT = -1; //This will be used to store users pref

integer CH_ATTACH_POINT = -29394;
integer GI_ATTACH_HANDLE;

integer debug_flag = TRUE; //set to false to turn off debug messages
DEBUG(list vars) { llOwnerSay( llList2CSV(vars)); } //We use SAY/DEBUG_CHANNEL because that shows up while we have busy flag on :)

//This is for public speech mainly. -1 will give owner say, any other will be channel, but allows for general override
SAY(string msg, integer channel) { if(channel == -1) llOwnerSay(msg); else llSay(channel, msg); } 

integer fn_easyDialog( key id, string message, list buttons, integer channel ) {
    llDialog( id, message, fn_validateLength(buttons), channel);
    return llListen(channel, "", id, "");    //now we can just switch it off when done.
}

//Flip the hud to either prefs or main panel
integer fn_flip_hud( integer current ){
    if(current == FALSE) {
        llSetLocalRot(GR_HUD_PREFS);
    } else {
        llSetLocalRot(GR_HUD_ROTATION);
    }
    return !current;
}

//Show/Hid the hud
integer fn_show_hide_hud( integer current ){
    if(current == TRUE) { //so hide it
        //Using LINK_ALL_OTHERS instead of BUTTON_SHOW for safety while dev'ing. @TODO change later.
        GV_USER_OFFSET = llGetLocalPos();//get the users last position, to restore later.

        llSetPos(fn_make_hidePos(llGetAttached(), GV_HIDE_OFFSET));
                        
                //Lets any other prim waiting for the hide event trigger
        llMessageLinked( LINK_ALL_OTHERS ,  SHOW_NUM, "hide", NULL_KEY );
    } else {
        llSetPos(GV_USER_OFFSET);

                //Lets any other prim waiting for the show event trigger
        llMessageLinked( LINK_ALL_OTHERS ,  SHOW_NUM, "show", NULL_KEY );
    }

    return !current;
}


integer fn_getIndex(list foo, string name) {
    return llListFindList(foo, [name] );
}

//fn_isHudPoint
//Returns either integer # of the attach point if hud, or false if its not 
integer fn_isHudPoint(integer attach_point) {
    if(attach_point > 30){
        return attach_point;
    } else {
        return FALSE;
    }
}

integer fn_setHudPos(vector localpos, rotation localrot) {
    llSetPos(localpos);
    llSetLocalRot(localrot);
    return TRUE;
}

//For buttons
list fn_validateLength( list foo) {
    integer li_return_length = 12;
    if( llGetListLength(foo) > li_return_length) {
        return llDeleteSubList( foo, 12, -1);
    }
    return foo;
}

//These seem similar, can probably be combined, but was simpler to keep them seperate.

//Takes in the offsets, and the attach point 
vector fn_makePos(integer attach_point, vector offset) {
    if ((attach_point == 31) || (attach_point == 35)) { //center 2 & center        
        return <0,0,0>;
    } else if (attach_point == 32) { // Top right
        return <offset.x, offset.y, offset.z * -1>;
    } else if (attach_point == 33) { // Top
        return <offset.x, 0, offset.z * -1>;
    } else if (attach_point == 34) { // Top Left
        return <offset.x, offset.y * -1, offset.z * -1>;
    } else if (attach_point == 36) { // Bottom Left
        return <offset.x, offset.y * -1 , offset.z>;
    } else if (attach_point == 37) { // Bottom
        return <offset.x, 0, offset.z>;
    } else if (attach_point == 38) { // Bottom Right - Baseline
        return offset;
    } else { //Not a HUD point? Then return it's current pos
        return llGetLocalPos();
    }
}

//Takes in the offsets, and the attach point 
vector fn_make_hidePos(integer attach_point, vector offset) {
    if ((attach_point == 31) || (attach_point == 35)) { //center 2 & center        
        return <0,-1.19,0>;
    } else if (attach_point == 32) { // Top right
        return <offset.x, offset.y, offset.z * -1>;
    } else if (attach_point == 33) { // Top
        return <offset.x, 0, offset.z>;
    } else if (attach_point == 34) { // Top Left
        return <offset.x, offset.y * -1, offset.z * -1>;
    } else if (attach_point == 36) { // Bottom Left
        return <offset.x, offset.y * -1 , offset.z>;
    } else if (attach_point == 37) { // Bottom
        return <offset.x, 0, offset.z * -1>;
    } else if (attach_point == 38) { // Bottom Right - Baseline
        return offset;
    } else { //Not a HUD point? Then return it's current pos
        return llGetLocalPos();
    }
}


//Once you have your HUD positions (BOTTOM RIGHT) and Rotated just right, put this script into the root prim.
//In the state entry, you will get the position (which is the offset) and rotation. Plug those into the top of your script, and remove the garbage from state_entry
default
{
    state_entry() {
        //////DELETE ME BEGIN
        llOwnerSay("Offset Info: "+(string)llGetLocalPos());
        llOwnerSay("Rotation Info: "+(string)llGetLocalRot());
        //DEBUG([llGetLocalPos(), llGetLocalRot()]);
        //////DELETE ME END
    }

    attach(key attached) {
        if (attached != NULL_KEY) {
            //Reset the Kill switch
            llSetTimerEvent(0.0);
            GI_KILL_COUNTER = 0;
            
            if(LAST_ATTACH_POINT != llGetAttached()){
                fn_setHudPos(fn_makePos(llGetAttached(),GV_OFFSET ), GR_HUD_ROTATION );
                LAST_ATTACH_POINT = llGetAttached();                
               // DEBUG(["setting last attach point"]);
            }

            //Flip it to front
            if(GI_HUD_FLIPPED == TRUE) {
                GI_HUD_FLIPPED=fn_flip_hud(GI_HUD_FLIPPED);
            }
        } else {
            llSetTimerEvent(TICKS); //This will pester owner  seconds to come pick up their item, and do kill switch. Clean up your litter kids!
        }
    }

    changed(integer change)
    {
        if (change & CHANGED_OWNER) {
            llResetScript();
        }
    }

    listen( integer chan, string name, key id, string msg ) {
        if(chan == CH_ATTACH_POINT) {
                        
                        //Done with the listen, so let's clean up, shall we?
            llListenRemove(GI_ATTACH_HANDLE); 
            
                        //DEBUG([llList2Integer(GL_HUD_NUMBERS, fn_getIndex(GL_HUD_NAMES, msg)), msg]);
            llAttachToAvatar(llList2Integer(GL_HUD_NUMBERS, fn_getIndex(GL_HUD_NAMES, msg)));
        }
    }

    on_rez(integer start_param) {
        if (!fn_isHudPoint(llGetAttached())){
            llOwnerSay("Please! Let me attach to your HUD, won't you?");
            llRequestPermissions(llGetOwner(), PERMISSION_ATTACH);
            llSetTimerEvent(TICKS);
        }
    }

    run_time_permissions(integer perm) {
        if (perm & PERMISSION_ATTACH) {
            GI_ATTACH_HANDLE = fn_easyDialog( llGetOwner(), "Pick a HUD Attach Point.", GL_HUD_NAMES, CH_ATTACH_POINT);
        } else {
            llOwnerSay("Please let me attach! Attachment is my purpose! My Life!");
        }
    }

    timer() {
        //DEBUG([GI_KILL_COUNTER]);
        GI_KILL_COUNTER++;
        if(GI_KILL_SWITCH == TRUE) {
            if(GI_KILL_COUNTER > GI_KILL_MAX){
                llInstantMessage(llGetOwner(), "I die now!");
                llDie();
            }
        }

        string message = "Come Get me! I am here. "+ llGetRegionName()+" - "+ (string)llGetPos();
        if(GI_KILL_SWITCH == TRUE) {
            message += " I will clean myself up if you don't pick me up after a while."; 
        }

        llInstantMessage(llGetOwner(), message);
        llSetTimerEvent(TICKS * (float)GI_KILL_COUNTER);
    }

    touch_start(integer num_detected) {
      //  DEBUG([llDetectedLinkNumber(0)]);
        if((llDetectedLinkNumber(0) == GI_BUTTON_FLIP) || (llDetectedLinkNumber(0) == GI_BUTTON_FLIP_B)) { 
            GI_HUD_FLIPPED=fn_flip_hud(GI_HUD_FLIPPED);
        } else if((llDetectedLinkNumber(0) == GI_BUTTON_SHOW) || (llDetectedLinkNumber(0) == GI_BUTTON_HIDE)) { 
            GI_VISIBLE= fn_show_hide_hud(GI_VISIBLE);
        }
    }


}